こんにちはゲストさん。会員登録(無料)して質問・回答してみよう!

解決済みの質問

エクセルの関数で値の判定

A1セルの値が、0より大きい数値または文字列の「USA」か「UK」の場合のみTRUEを返したいのです。
=OR(A1>0,A1={"USA","UK"})
としてみましたが、AとかBとかの文字列も0より大きいとみなされるようでTRUEになってしまいます。
やむをえす、
=OR(AND(ISNUMBER(A1),A1>0),A1={"USA","UK"})
としてみましたが、もっと簡単に判定する方法はないでしょうか?
エクセル2013です。

投稿日時 - 2019-04-17 20:38:25

QNo.9607798

困ってます

質問者が選んだベストアンサー

>もっと簡単に判定する方法はないでしょうか?
ISNUMBER(A1)とCOUNT(A1)は同等の結果を得られ、ANDは四則演算の*と等価になることを利用して次のようにすると良いでしょう。
=OR(A1>0,A1={"USA","UK"})
      ↡
=OR(COUNT(A1)*(A1>0),A1={"USA","UK"})

投稿日時 - 2019-04-18 09:12:46

お礼

=OR(COUNT(A1)*(A1>0),A1={"USA","UK"})
いいですね!!

投稿日時 - 2019-04-19 13:03:49

ANo.2

このQ&Aは役に立ちましたか?

0人が「このQ&Aが役に立った」と投票しています

回答(5)

ANo.5

私のミスでご迷惑をお掛けしました。
で、やり直して完成したのでご連絡します。

図中のB5セルが検査対象になります。
E3は最終判定になります。

E5は数字の判定
E6は対象の文字判定となります。

それぞれの関数と説明が以下の通りです。

【E5】
ISNUMBERを使用しました。
=IF(ISNUMBER(B5)=TRUE,IF(B5>0,"TRUE","FALSE"),"FALSE")

【E6】
普通にIF文使用。
=IF(B5="USA","TRUE",IF(B5="UK","TRUE","FALSE"))

【E3】
普通にIF文使用。
=IF(E5="TRUE","TRUE",IF(E6="TRUE","TRUE","FALSE"))

ややこしくなりましたが、ORが文字列処理において、文字コードを引用しているような雰囲気でした。
もしくは文字処理では不適合である。

投稿日時 - 2019-04-19 00:41:35

お礼

ありがとうござます。
ただ、これじゃ最初に提示させていただいた
=OR(AND(ISNUMBER(A1),A1>0),A1={"USA","UK"})
のほうが簡単じゃないですか?

投稿日時 - 2019-04-19 12:51:28

ANo.4

下記(注)の理由から、自信ないが =OR(N(A2)>0,A2="USA",A2="UK")
例と結果 
A2 B2 セル以下
2TRUE
-1FALSE
USATRUE
UKTRUE
OMFALSE
tuFALSE
USAAFALSE
USATRUE
87TRUE
xcFALSE
A2>0とすると、文字列の場合も、この判定するようで、Nで数値化して、それを避けた。(注)数値の場合の条件が、>=0だとだめですが。
https://kokodane.com/kansu_info_16.htm

投稿日時 - 2019-04-18 15:28:31

お礼

imogasiさん、ありがとうございます。
なるほど、これはすごい!!
数値の場合の条件が、>0なのでぴったり!!・・・・と思ったのですが。
唯一、TRUEを入れられた場合(そんなことはまずないはずですが)、N関数では1になってTRUEが返っちゃいます。残念

投稿日時 - 2019-04-19 12:49:42

ANo.3

こんなのはどうでしょう
=OR(COUNTIF(A1,">0"),A1={"UK","USA"})

投稿日時 - 2019-04-18 10:08:05

お礼

ありがとうございます。
これいいですね!

投稿日時 - 2019-04-19 13:03:06

ANo.1

これで出来ました。
=OR(A1>0,D1,D2)

対象はA1
D1にUSA、D2にUKを入力
そのセル参照でOK

実際の画面がこちら↓ これでA1が0以上またはUSAまたはUKでTRUEを返します。

投稿日時 - 2019-04-17 21:14:25

お礼

早速ありがとうございます。
=OR(A1>0,A1={"USA","UK"}) と同じ結果です。
A1にROCとかJPNが入っても A1>0 となるようでTRUEが帰ります。

投稿日時 - 2019-04-18 08:58:04

あなたにオススメの質問