こんにちはゲストさん。会員登録(無料)して質問・回答してみよう!

解決済みの質問

スペースを含んだ文字列から文字列の抽出

エクセルバージョン2007

スペースを含む文字列で、A列に文字列がある時、以下の式を組んで文字列を抽出しています。
先頭にIDの数字が有る場合は、それぞれの目的に合った文字列を抽出しています。

B1=LEFT(A1,SEARCH(" ",A1,1)-1)

C1=LEFT(MID(A1,SEARCH(" ",A1,1)+1,LEN(A1)-SEARCH(" ",A1,1)),SEARCH(" ",MID(A1,SEARCH(" ",A1,1)+1,LEN(A1)-SEARCH(" ",A1,1)),1)-1)

3 3df-32654-10 CCCCHH
10 1ab-12345-00 AAABBBB

この文字列の場合、B列に3と10が表示、C列に 3df-32654-10 1ab-12345-00が表示されます。

先頭に、IDの無い文字列は以下の様な構成です。

6rt-95132-00 PPPKKK
この文字列の場合、B列に6rt-95132-00、C列にPPPKKKが表示されてしまい、この場合、IDの数字が無い場合はB列には表示させない又は、C列に6rt-95132-00させたいと思っています。

ご教授頂ければ幸いです。

以上、宜しくお願い致します。

投稿日時 - 2018-12-18 19:06:45

QNo.9569013

困ってます

質問者が選んだベストアンサー

ANo.3です

> B1:=IF(LEN(A1)-LEN(SUBSTITUTE(A1," ",""))>1,LEFT(A1,SEARCH(" ",A1)-1),"")
>
> 文字列を再確認しましたら、スペースが最大5つ有りました。この式の >1 の部分の1を3や4に増やしましたら、同じ様に表現出来ました。
> 式の使い方は、合っていますでしょうか?

このB1の式は、「文字列中に半角スペースが2個以上あれば先頭の一塊はID。1つ以下ならIDでは無いので空白」としています。
しかし、文字列の形式が提示された以外にも色々ありそうなので、B1の式を以下の様に変更したいと思います。

B1:=IF(ISERROR(LEFT(A1,SEARCH(" ",A1,1)-1)*1),"",LEFT(A1,SEARCH(" ",A1,1)-1))

これは、「先頭の一塊が数値でないなら空白、数値ならID」です。

投稿日時 - 2018-12-18 23:33:57

お礼

補足に対して、ご回答頂きありがとうございました。
これで、全てに対して対応出来ます。

投稿日時 - 2018-12-19 06:44:42

ANo.4

このQ&Aは役に立ちましたか?

0人が「このQ&Aが役に立った」と投票しています

回答(4)

ANo.3

Excel2007だとこんな感じかな?
B1:=IF(LEN(A1)-LEN(SUBSTITUTE(A1," ",""))>1,LEFT(A1,SEARCH(" ",A1)-1),"")
C1:=TRIM(MID(IF(B1="",REPT(" ",100),"")&SUBSTITUTE(A1," ",REPT(" ",100)),100,100))

投稿日時 - 2018-12-18 20:34:34

補足

B1:=IF(LEN(A1)-LEN(SUBSTITUTE(A1," ",""))>1,LEFT(A1,SEARCH(" ",A1)-1),"")

文字列を再確認しましたら、スペースが最大5つ有りました。この式の >1 の部分の1を3や4に増やしましたら、同じ様に表現出来ました。
式の使い方は、合っていますでしょうか?

投稿日時 - 2018-12-18 21:13:10

ANo.2

B1=IFERROR(TEXT(LEFT(A1,FIND(" ",A1)-1)*1,"0"),"")
C1=LEFT(TRIM(SUBSTITUTE(A1,B1,"")),FIND(" ",TRIM(SUBSTITUTE(A1,B1,"")))-1)

投稿日時 - 2018-12-18 20:22:15

お礼

ご回答頂きありがとうございました。

投稿日時 - 2018-12-19 06:40:19

ANo.1

Q、” " で区切られた文字列を取り出す要領は?
A、逆順に抜き出せばよいと思います。

 Excel は操作したことのない完全など素人。ですから、考え方だけ。思うに、” " で区切られた文字列を先頭から抜き出すのではなくて、逆順に抜き出せば容易に目的は達成されられると思います。

投稿日時 - 2018-12-18 20:06:55

お礼

ご回答頂きありがとうございました。

投稿日時 - 2018-12-19 06:39:55

あなたにオススメの質問