こんにちはゲストさん。会員登録(無料)して質問・回答してみよう!

解決済みの質問

エクセル2000にてSUM,SUMIF,IF関数のどれかを用いた集計方法

エクセル2000にてA1 からA10列には1000円から2000円までの金額、B1からB10列にはA列の金額に応じた手数料が入力されているとします。関数を使用し金額が1200円から1700円における手数料の合計を求めるにはどのように入力したらよいでしょうか?SUM関数、SUMIF関数、IF関数のいずれかを使用した場合を教えてください。

投稿日時 - 2003-08-16 19:56:43

QNo.629503

暇なときに回答ください

質問者が選んだベストアンサー

(テストデータ)
A1:B10
12001
10002
13003
10004
13005
17006
18007
19008
20009
150010
(関数式)
C1に出すとして
C1に
=SUMIF(A1:A10,"<=1700",B1:B10)-SUMIF(A1:A10,"<1200",B1:B10)
(結果)25

投稿日時 - 2003-08-16 21:13:13

お礼

わかりやすいご回答ありがとうございました。大変参考になりました。ずっと悩んでいたのでこれですっきりしました!

投稿日時 - 2003-08-17 13:45:09

ANo.4

このQ&Aは役に立ちましたか?

0人が「このQ&Aが役に立った」と投票しています

回答(6)

ANo.6

SUMPRODUCTなどありなら、DSUMもあります。
(テストデータ)
A1:B11
金額手数料
12001
10002
13003
10004
13005
17006
18007
19008
20009
150010
見だしの
金額手数料は必須。
(条件)
D1:E2に
金額金額
<=1700>=1200
(関数式)
どこでもデータの無いところへ
=DSUM(A1:B11,"手数料",D1:E2)
手数料は""で囲むこと。
(結果)
25

投稿日時 - 2003-08-16 22:19:59

ANo.5

みなさん こんばんは

=SUM(SUMIF(A1:A10,{">=1200",">1700"},B1:B10)*{1,-1})

投稿日時 - 2003-08-16 21:29:25

お礼

わかりやすいご回答ありがとうございました。大変参考になりました。ずっと悩んでいたのでこれですっきりしました!

投稿日時 - 2003-08-17 13:49:15

ANo.3

IFを使用した場合です。
C1に=IF(AND(A1>=1200,A1<=1700),B1,0)
と入力しC10までコピーします。
これで金額1200~1700までの手数料がC列に抽出されますので、あとはSUM(C1.C10)を好きなセルで使い合計は出せます。

投稿日時 - 2003-08-16 21:00:57

お礼

わかりやすいご回答ありがとうございました。大変参考になりました。ずっと悩んでいたのでこれですっきりしました!

投稿日時 - 2003-08-17 13:30:49

ANo.2

> SUM関数、SUMIF関数、IF関数のいずれかを使用した場合を教えてください。

その関数を使用する条件ですと配列を使用することになると思います。

=SUM((A1:A10>=1200)*(A1:A10<=1700)*B1:B10)

を入力して Ctrl + Shift + Enter を押します。

配列を使用しない方法では、指定の関数ではありませんが、

=SUMPRODUCT((A1:A10>=1200)*(A1:A10<=1700)*B1:B10)

投稿日時 - 2003-08-16 20:52:33

お礼

わかりやすいご回答ありがとうございました。大変参考になりました。ずっと悩んでいたのでこれですっきりしました!

投稿日時 - 2003-08-17 13:21:52

ANo.1

手始めに、資料の入力が終わったら、オートSUMを使ってみてはいかがですか?
ツールバーの Σ ボタンをクリックするだけで集計は完了します。
試してみてください。

投稿日時 - 2003-08-16 20:42:10

補足

ご回答ありがとうございます。説明不足ですいません。A列から検索条件(1200円以上1700円以下)にあてはまる値に対応するB列の合計を抽出したかったのです。例えば=SUM(IF(A1:A5>=1200,IF(A1:A5<=1700,B1:B5,0)))などと組みましたが出来ませんでした。SUMIFは二個以上の条件式は組めないので。。。実際の処理は500行のデータが数多くあり、A列とB列の間には規則性がなく関係式も導けないのです

投稿日時 - 2003-08-16 20:48:25

お礼

ご助言ありがとうございました。またよろしくおねがいします。

投稿日時 - 2003-08-17 13:19:55

あなたにオススメの質問