こんにちはゲストさん。会員登録(無料)して質問・回答してみよう!

解決済みの質問

エクセルで同一セルから数字のみ取り出し

エクセル2003、計算式が理解できる老人会青年部新米会計です。
A1のセルに  落札:400円 と入ってます。400だけを取り出して
B1のセルに入れたいのです。
A2のセルは  送料:1230円と入ってます 1230を取り出して
B2のセルに入れたいのです。
    A         B
1 落札価格:400円    400
2 送料:  1230円   1230
3 手数料: 100円    100
4       SUM    1730
文字は同じ文字だけです。金額は変動します。
合計を出したいのです。
よろしくおねがいします。

投稿日時 - 2007-03-14 17:40:41

QNo.2832801

困ってます

質問者が選んだベストアンサー

一例ですが次の方法は如何でしょうか。
A1セルの書式設定→表示形式→ユーザ定義で"落札価格:"#,##0"円"
A2セルの書式設定→表示形式→ユーザ定義で"送料:"#,##0"円"
A3セルの書式設定→表示形式→ユーザ定義で"手数料:"#,##0"円"
とすれば、B1は=A1、B2は=A2,B3は=A3で取り出せます。(但し、B列のセルの書式設定で表示形式を標準として下さい)

因みにA4セルの書式設定→表示形式→ユーザ定義で"合計:"#,##0"円"として、=SUM(A1:A3)とすれば、B列に数値を抽出することなく合計も表示できます。

投稿日時 - 2007-03-14 18:00:24

お礼

みなさんありがとうございます。質問の仕方がわるかったです。
ご親切にありがとうございます。
もう1回考えて質問してみます。
ありがとうございました。

投稿日時 - 2007-03-14 19:20:51

ANo.2

このQ&Aは役に立ちましたか?

0人が「このQ&Aが役に立った」と投票しています

回答(5)

ANo.5

=SUBSTITUTE(TRIM(MID(A1,FIND(":",A1)+1,100)),"円","")*1
MIDで":"以降の文字列をFINDで取り出して
TRIMでスペース消去
SUBSUTITUTEで"円"を消去
文字を*1で数値化

実際の表の作り方は前の方の言うとおりで
数字の部分だけのセル(列)にしたほうがいいですね。

投稿日時 - 2007-03-14 18:20:51

補足

ありがとうございます。説明が悪かったです。
落札価格:400円   
送料:  1230円   
手数料: 100円 
これはオークションの落札メールをまとめてコピーして
貼り付けます。住所 電話 郵便番号などを
わかり易い用にして発送シールなどを作ります。
説明下手でごめんなさい。  

投稿日時 - 2007-03-14 18:22:25

ANo.4

B1=LOOKUP(10^10,RIGHT(SUBSTITUTE(A1,"円",),COLUMN(1:1))*1)

◆出来なくはありませんが、No3 の方のご指摘のように、項目名と金額は別のセルに入力するようにされたほうがいいと思います

投稿日時 - 2007-03-14 18:18:51

ANo.3

B1の式は
=MID(A1,MIN(FIND({1,2,3,4,5,6,7,8,9,0},A1&"1234567890")),FIND("円",A1)-MIN(FIND({1,2,3,4,5,6,7,8,9,0},A1&"1234567890")))*1
です。

でもこれはシートの設計が悪いですよ。はじめから、
A列     B列 
落札価格   400
送料     1230
と入力してB列の書式を「#,##0"円"」のようにするべきです。
そうでないと上記のような長い式をひねり出さないとならなくなります

投稿日時 - 2007-03-14 18:08:24

ANo.1

表示の問題で、そもそも400円とか1230円とかの列は書式でユーザ定義し、
########円としておけば、数字だけを入力すると円が付きます。
となりの列には = のみで表示を単に数値にしたら円が付きません。
というか、円が付いてもSUM出来ますし。

投稿日時 - 2007-03-14 17:56:47

あなたにオススメの質問